# Maintainer: Alexey Pavlov <Alexpux@gmail.com>

pkgname=tftp-hpa
pkgver=6.0
pkgrel=1
pkgdesc="Official tftp server"
arch=('i686' 'x86_64')
url="https://www.kernel.org/pub/software/network/tftp/tftp-hpa/"
msys2_repository_url='https://kernel.googlesource.com/pub/scm/network/tftp/tftp-hpa.git'
msys2_references=(
  "anitya: 4962"
  "cpe: cpe:2.3:a:tftpd-hpa_project:tftpd-hpa"
)
license=('spdx:BSD-4-Clause-UC')
depends=('libreadline>=6.0.00')
makedepends=('libreadline-devel' 'gcc' 'autotools')
source=(https://www.kernel.org/pub/software/network/tftp/${pkgname}-${pkgver}.tar.xz
        LICENSE
        02-missing-header.patch
        03-add-header-include-path.patch
        )
sha256sums=('76e3fbfd10ae3f55870f5f7e0ddb7fb2c424aa0f8fbecbae4a23ffe1aa1b964e'
            '628639fd20f1716bfd71a8bc4bf983fd16eb004cc1ec5a4abf99e6618cfcb870'
            'd9f494250b09fee09434f4a4bd91284fcda5d56e5fbd548bb0b2b759143830ee'
            '3d3619e5d0b47a1337aeeaf0570beb35259d7edc23d7cc0a21302a3a9967e46c')

prepare() {
  cd ${pkgname}-${pkgver}

  patch -Np2 -i ${srcdir}/02-missing-header.patch
  patch -Np1 -i ${srcdir}/03-add-header-include-path.patch

  ./autogen.sh
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure --prefix=/usr \
    --build=${CHOST} \
    --mandir=/usr/share/man \
    --sbindir=/usr/bin \
    ac_cv_header_winsock_h=no \
    ac_cv_header_winsock2_h=no

  make
}

package() {
  cd ${pkgname}-${pkgver}
  make INSTALLROOT="${pkgdir}" install
  install -D -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  # Remove server files
  rm "${pkgdir}/usr/bin/in.tftpd"
  rm "${pkgdir}/usr/share/man/man8/in.tftpd.8"
  rm "${pkgdir}/usr/share/man/man8/tftpd.8"

  # Install tftp header
  install -Dm 644 headers/arpa/tftp.h ${pkgdir}/usr/include/arpa/tftp.h
}
