# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>
# stolen from Archlinux

pkgname='re2c'
pkgver=4.6
pkgrel=1
pkgdesc='A tool for generating C-based recognizers from regular expressions'
arch=('i686' 'x86_64')
url='https://re2c.org/'
msys2_repository_url='https://github.com/skvadrik/re2c'
msys2_changelog_url='https://re2c.org/releases/changelog/changelog.html'
msys2_references=(
  'anitya: 7664'
  'archlinux: re2c'
  'cpe: cpe:/a:re2c:re2c'
  'gentoo: dev-util/re2c'
)
license=('spdx:LicenseRef-re2c')
depends=('gcc-libs')
makedepends=(
  'cmake'
  'gcc'
  'ninja'
  'python'
)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/skvadrik/re2c/archive/${pkgver}.tar.gz")
sha256sums=('39af7f5ccaa0b7cf8105fa59a02566b52bc8844e59982133165487ffd1cfc6cc')

build() {
  cd "${pkgname}-${pkgver}"

  local _cmake_options=(
    -GNinja
    -DCMAKE_INSTALL_PREFIX=/usr
  )

  cmake "${_cmake_options[@]}" -S . -B build

  cmake --build build
}

check() {
  cd "${pkgname}-${pkgver}"

  cmake --build build --target check
}

package() {
  cd "${pkgname}-${pkgver}"

  DESTDIR="${pkgdir}" cmake --install build

  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
