# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname='setuptools-scm'
_pyname="${_realname/-/_}"
pkgbase="python-${_realname}"
pkgname="python-${_realname}"
pkgver=10.2.3
pkgrel=1
pkgdesc='Handles managing your python package versions in scm metadata'
arch=('any')
url='https://setuptools-scm.readthedocs.io/'
msys2_repository_url='https://github.com/pypa/setuptools-scm'
msys2_documentation_url='https://setuptools-scm.readthedocs.io'
msys2_changelog_url='https://setuptools-scm.readthedocs.io/latest/changelog'
msys2_references=(
  'anitya: 7874'
  'archlinux: python-setuptools-scm'
  'gentoo: dev-python/setuptools-scm'
  'purl: pkg:pypi/setuptools-scm'
)
license=('spdx:MIT')
depends=(
  'python'
  'python-packaging'
  'python-setuptools'
  'python-typing_extensions'
  'python-vcs-versioning'
)
makedepends=(
  'python-build'
  'python-installer'
)
checkdepends=(
  'python-pytest'
  # useful for check but not available in msys repo
  # 'python-pytest-timeout'
  # 'python-pytest-xdist'
)
options=('!strip')
source=("https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
sha256sums=('f179ed3e2a63cf5823e5ee9aa9ca08386219400443a0553224d72dde3f206b44')

build() {
  cd "${_pyname}-${pkgver}"

  # tell setuptools-scm to use the PKGBUILD's version string
  export SETUPTOOLS_SCM_PRETEND_VERSION="$pkgver"

  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd "${_pyname}-${pkgver}"

  PYTHONPATH="${PWD}/src" pytest || warning "Tests failed"
}

package() {
  cd "${_pyname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
