# Maintainer: João Guerra <joca.bt@gmail.com>

pkgbase='python-pygments'
pkgname=('python-pygments')
pkgver=2.21.0
pkgrel=1
pkgdesc='A syntax highlighting engine written in Python'
arch=('i686' 'x86_64')
url='https://pygments.org/'
msys2_repository_url='https://github.com/pygments/pygments'
msys2_documentation_url='https://pygments.org/docs'
msys2_changelog_url='https://pygments.org/docs/changelog'
msys2_references=(
  'anitya: 3986'
  'archlinux: python-pygments'
  'cpe: cpe:/a:pygments:pygments'
  'gentoo: dev-python/pygments'
  'purl: pkg:pypi/pygments'
)
license=('spdx:BSD-2-Clause')
depends=('python')
makedepends=(
  'python-build'
  'python-hatchling'
  'python-installer'
)
provides=('python3-pygments')
conflicts=('python3-pygments')
replaces=('python3-pygments')
source=("https://pypi.python.org/packages/source/p/pygments/pygments-${pkgver}.tar.gz")
sha256sums=('610ca751c9bc2492b38eb9a38a7fbc93edbbb2d7182edaf34e66ae493dee5c8c')

build() {
  cd "pygments-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "pygments-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 external/pygments.bashcomp "${pkgdir}/usr/share/bash-completion/completions/pygmentize"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
