# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>

_realname='attrs'
pkgbase="python-${_realname}"
pkgname="python-${_realname}"
pkgver=26.1.0
pkgrel=1
pkgdesc='Attributes without boilerplate.'
arch=('any')
url='https://www.attrs.org/'
msys2_repository_url='https://github.com/python-attrs/attrs'
msys2_references=(
  'archlinux: python-attrs'
  'cpe: cpe:/a:attrs_project:attrs'
  'gentoo: dev-python/attrs'
  'purl: pkg:pypi/attrs'
)
license=('spdx:MIT')
depends=(
  'python'
)
makedepends=(
  'python-build'
  'python-hatch-fancy-pypi-readme'
  'python-hatch-vcs'
  'python-hatchling'
  'python-installer'
)
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha512sums=('f9ae9f3a3d313c5f111870d14308fdbb3e2d75a077e76a3b8304d6b9688902c256d7d5b097eaa41e674c29db08c5034e635ee564252096c62f64b6b817f145ae')

build() {
  cd "${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
