# Maintainer: Bartlomiej Piotrowski <nospam@bpiotrowski.pl>

pkgname=pkgconf
pkgver=3.0.7
pkgrel=1
pkgdesc='pkg-config compatible utility which does not depend on glib'
arch=('i686' 'x86_64')
url='http://pkgconf.org'
msys2_repository_url='https://github.com/pkgconf/pkgconf'
msys2_changelog_url='https://github.com/pkgconf/pkgconf/blob/main/NEWS'
msys2_references=(
  'anitya: 12753'
  'archlinux: pkgconf'
  'cpe: cpe:/a:pkgconf:pkgconf'
  'gentoo: dev-util/pkgconf'
)
license=('spdx:ISC')
makedepends=(
  'gcc'
  'meson'
  'ninja'
)
conflicts=('pkg-config')
provides=('pkg-config')
replaces=('pkg-config')
source=("https://github.com/pkgconf/pkgconf/archive/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.gz")
noextract=("${pkgname}-${pkgver}.tar.gz")
sha256sums=('a9ae678879771fcf15247ac2435e7ad8308be8a5921898e6720b3b8949410f73')

prepare() {
  # fixes encoding: tests/lib1/te\360\237\230\213st/
  bsdtar -xf "${pkgname}-${pkgver}.tar.gz" || true

  mv "${pkgname}-${pkgname}-${pkgver}" "${pkgname}-${pkgver}"
}

build() {
  cd "${pkgname}-${pkgver}"

  local _meson_options=(
    --prefix=/usr
    --buildtype=plain
  )

  meson setup build "${_meson_options[@]}"
  meson compile -C build
}

package() {
  cd "${pkgname}-${pkgver}"

  meson install -C build --destdir "${pkgdir}"

  cp "${pkgdir}/usr/bin/pkgconf" "${pkgdir}/usr/bin/${CHOST}-pkg-config"
  cp "${pkgdir}/usr/bin/pkgconf" "${pkgdir}/usr/bin/pkg-config"
}
