# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname='LWP-MediaTypes'
pkgname="perl-${_realname}"
pkgver=6.05
pkgrel=1
pkgdesc='Guess the media type of a file or a URL'
arch=('any')
url='https://metacpan.org/dist/LWP-MediaTypes'
msys2_repository_url='https://github.com/libwww-perl/LWP-MediaTypes'
msys2_changelog_url='https://metacpan.org/dist/LWP-MediaTypes/changes'
msys2_references=(
  'anitya: 3047'
  'archlinux: perl-lwp-mediatypes'
  'gentoo: dev-perl/LWP-MediaTypes'
  'purl: pkg:cpan/OALDERS/LWP-MediaTypes'
)
license=('spdx:Artistic-1.0-Perl OR GPL-1.0-or-later')
groups=('perl-modules')
depends=('perl')
options=('!emptydirs')
source=("https://www.cpan.org/authors/id/O/OA/OALDERS/${_realname}-${pkgver}.tar.gz")
sha256sums=('abb2dcfbf069317fe65b098e3b2ad58c5eb33e9a839b9190cce6d371f8966cc1')

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_realname}-${pkgver}"

  make test
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"

  make DESTDIR="${pkgdir}" install
}
