# Contributor: Dirk Stolle

_realname=Class-Inspector
pkgname=perl-${_realname}
pkgver=1.36
pkgrel=1
pkgdesc="Get information about a class and its structure"
arch=('i686' 'x86_64')
license=('spdx:GPL-1.0-only' 'spdx:Artistic-1.0-Perl')
url='https://metacpan.org/dist/Class-Inspector'
msys2_repository_url='https://github.com/uperl/Class-Inspector'
msys2_changelog_url='https://github.com/uperl/Class-Inspector/blob/main/Changes'
msys2_references=(
  "archlinux: perl-class-inspector"
  "cygwin: perl-Class-Inspector"
  "purl: pkg:cpan/PLICEASE/Class-Inspector"
)
groups=('perl-modules')
depends=('perl')
makedepends=('perl-devel' 'make')
checkdepends=('perl-Test-Pod')
options=('!emptydirs')
source=("https://www.cpan.org/authors/id/P/PL/PLICEASE/${_realname}-${pkgver}.tar.gz")
sha256sums=('cc295d23a472687c24489d58226ead23b9fdc2588e522f0b5f0747741700694e')

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make test
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make install DESTDIR="${pkgdir}"
}
