# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=Alien-Build
pkgname=perl-${_realname}
pkgver=2.87
pkgrel=1
pkgdesc="Build external dependencies for use in CPAN"
arch=('any')
license=('spdx:Artistic-1.0-Perl' 'spdx:GPL-1.0-or-later')
url="https://metacpan.org/dist/Alien-Build"
msys2_changelog_url='https://metacpan.org/dist/Alien-Build/changes'
msys2_repository_url='https://github.com/PerlAlien/Alien-Build'
msys2_references=(
  'purl: pkg:cpan/PLICEASE/Alien-Build'
)
groups=('perl-modules')
depends=('perl-Capture-Tiny' 'perl-FFI-CheckLib' 'perl-File-chdir' 'perl-File-Which' 'perl-Path-Tiny')
makedepends=('perl-Test2-Suite' 'perl-devel')
#checkdepends=('perl-Alien-Base-ModuleBuild' 'perl-Alien-cmake3' 'perl-Env-ShellWords'
#              'perl-PkgConfig' 'perl-PkgConfig-LibPkgConf' 'perl-Readonly' 'perl-Sort-Versions')
options=(!emptydirs)
source=("https://cpan.metacpan.org/authors/id/P/PL/PLICEASE/${_realname}-${pkgver}.tar.gz")
options=(!emptydirs)
sha256sums=('b041d6e160fcad569bcc1bb314bbe1ea3679d0e5fd735f187a31bf77817e8254')

build() {
  cd "${_realname}-${pkgver}"

  # install module in vendor directories.
  perl Makefile.PL -- INSTALLDIRS=vendor
  make
}

check() {
  cd "${_realname}-${pkgver}"
  make test
}

package() {
  cd "${_realname}-${pkgver}"

  make install DESTDIR="${pkgdir}"
  # Remove .packlist and perllocal.pod files.
  find "$pkgdir" -name '.packlist' -delete
  find "$pkgdir" -name 'perllocal.pod' -delete
}
