# Maintainer: Jeremy Drake <github@jdrake.com>

pkgname=mm-common
pkgver=1.0.8
pkgrel=1
pkgdesc='Common build files of the C++ bindings'
url='https://gtkmm.gnome.org/'
msys2_repository_url='https://gitlab.gnome.org/GNOME/mm-common'
msys2_documentation_url='https://gtkmm.gnome.org/en/documentation.html'
msys2_changelog_url='https://gitlab.gnome.org/GNOME/mm-common/-/blob/master/NEWS'
msys2_references=(
  'anitya: 13152'
  'archlinux: mm-common'
  'gentoo: dev-cpp/mm-common'
)
arch=('i686' 'x86_64')
makedepends=('meson' 'gcc')
license=('spdx:GPL-2.0-or-later')
source=("https://download.gnome.org/sources/mm-common/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"
        https://gcc.gnu.org/onlinedocs/libstdc++/latest-doxygen/libstdc++.tag)
sha256sums=('b189ee636e839d12c00dabefae099fd488ab2358dec24d264761c011950b02a9'
            'cb01f8aebdb7b9874b100d13a006fb688ee25d2e93e02ff294e6c2483606c7a3')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cp ../libstdc++.tag doctags
}

build() {
  mkdir "${srcdir}/build-${CARCH}" && cd "${srcdir}/build-${CARCH}"
  meson setup \
    --buildtype=plain \
    --prefix=/usr \
    "../${pkgname}-${pkgver}"

  meson compile
}

check() {
  cd "${srcdir}/build-${CARCH}"
  meson test --print-errorlogs
}

package() {
  cd "${srcdir}/build-${CARCH}"
  DESTDIR="${pkgdir}" meson install
}
