# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgbase='libksba'
pkgname=('libksba' 'libksba-devel')
pkgver=1.8.1
pkgrel=1
pkgdesc='A CMS and X.509 access library'
arch=('i686' 'x86_64')
url='https://www.gnupg.org/related_software/libksba/'
msys2_repository_url='https://git.gnupg.org/cgi-bin/gitweb.cgi?p=libksba.git'
msys2_references=(
  'anitya: 1649'
  'archlinux: libksba'
  'cpe: cpe:/a:gnupg:libksba'
  'cpe: cpe:/a:libksba_library:libksba_library'
  'gentoo: dev-libs/libksba'
)
license=('spdx:LGPL-3.0-or-later OR GPL-2.0-or-later')
makedepends=(
  'autotools'
  'gcc'
  'libgpg-error-devel'
)
options=('strip' 'libtool')
source=("https://gnupg.org/ftp/gcrypt/${pkgbase}/${pkgbase}-${pkgver}.tar.bz2"{,.sig})
sha256sums=('c2f84393011827219ae117131dba8e7684c2bed0961eed11b0642c2acba440b5'
            'SKIP')
validpgpkeys=(
  '6DAA6E64A76D2840571B4902528897B826403ADA' # Werner Koch (dist signing 2020)
  'AC8E115BF73E2D8D47FA9908E98E9B2D19C6C8BD' # Niibe Yutaka (GnuPG Release Key)
)

prepare() {
  cd "${pkgbase}-${pkgver}"

  autoreconf -fiv
}

build() {
  cd "${pkgbase}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --build="${CHOST}" \
    --enable-shared \
    --disable-static

  make no_undefined=-no-undefined
  make "DESTDIR=${srcdir}/dest" install
}

check() {
  cd "${pkgbase}-${pkgver}"

  make check
}

package_libksba() {
  groups=('libraries')
  depends=(
    'gcc-libs'
    'libgpg-error'
  )

  mkdir -p "${pkgdir}/usr/bin"

  cp -f "${srcdir}/dest/usr/bin/"*.dll "${pkgdir}/usr/bin/"
  cp -rf "${srcdir}/dest/usr/share" "${pkgdir}/usr/"

  install -Dm644 "${srcdir}/${pkgbase}-${pkgver}/COPYING" "${pkgdir}/usr/share/licenses/libksba/COPYING"
}

package_libksba-devel() {
  pkgdesc='Libksba headers and libraries'
  groups=('development')
  depends=(
    'libgpg-error-devel'
    "libksba=${pkgver}"
  )
  options=('staticlibs')

  mkdir -p "${pkgdir}/usr/bin"

  cp -f "${srcdir}/dest/usr/bin/ksba-config" "${pkgdir}/usr/bin/"
  cp -rf "${srcdir}/dest/usr/include" "${pkgdir}/usr/"
  cp -rf "${srcdir}/dest/usr/lib" "${pkgdir}/usr/"
}
