# Maintainer : Gork             <bertsmithzp@gmail.com>
# Contributor: Christoph Reiter <reiter.christoph@gmail.com>

pkgname=fmt
pkgver=12.2.0
pkgrel=1
pkgdesc='Open-source formatting library for C++'
arch=(x86_64 i686)
url='https://fmt.dev'
msys2_repository_url='https://github.com/fmtlib/fmt'
msys2_documentation_url='https://fmt.dev'
msys2_changelog_url='https://github.com/fmtlib/fmt/blob/main/ChangeLog.md'
msys2_references=(
  'anitya: 11526'
  'archlinux: fmt'
  'cpe: cpe:/a:fmt:fmt'
  'gentoo: dev-libs/libfmt'
)
license=(spdx:MIT)
depends=(gcc-libs)
makedepends=(
  cmake
  ninja
  gcc
)
source=("https://github.com/fmtlib/fmt/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('8b852bb5aa6e7d8564f9e81394055395dd1d1936d38dfd3a17792a02bebd7af0')

build() {
  cmake -S "${pkgname}-${pkgver}" -B build \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DBUILD_SHARED_LIBS=ON
  cmake --build build
}
check() {
  cmake --build build --target test
}
package() {
  DESTDIR="${pkgdir}" cmake --build build --target install
  install -Dm 644 "${pkgname}-${pkgver}"/LICENSE -t "${pkgdir}"/usr/share/licenses/fmt/
}
