# Maintainer: Maksim Bondarenkov <maksapple2306@gmail.com>

_realname=dua-cli
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=2.38.1
pkgrel=1
pkgdesc="View disk space usage and delete unwanted data, fast (mingw-w64)"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://github.com/Byron/dua-cli'
msys2_repository_url='https://github.com/Byron/dua-cli'
msys2_changelog_url='https://github.com/Byron/dua-cli/blob/main/CHANGELOG.md'
msys2_references=(
  'archlinux: dua-cli'
  'purl: pkg:cargo/dua-cli'
)
license=('spdx:MIT')
makedepends=("${MINGW_PACKAGE_PREFIX}-rust")
source=("${msys2_repository_url}/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz")
sha256sums=('b30d76e60be8f4928c3b7d5c3cd2d9034d60ad09c7e044bf2056f01e8596f46e')

prepare() {
  cd "${_realname}-${pkgver}"

  cargo fetch --locked --target "${RUST_CHOST}"
}

build() {
  cd "${_realname}-${pkgver}"

  RUSTC_BOOTSTRAP=1 cargo build --release --frozen
}

check() {
  cd "${_realname}-${pkgver}"

  RUSTC_BOOTSTRAP=1 cargo test --release --frozen -- --skip "interactive"
}

package() {
  cd "${_realname}-${pkgver}"

  RUSTC_BOOTSTRAP=1 \
  cargo install \
    --offline \
    --no-track \
    --frozen \
    --path . \
    --root "${pkgdir}${MINGW_PREFIX}"

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
}
