# Contributor: Mehdi Chinoune <mehdi.chinoune@hotmail.com>
# Contributor: Justin Caselman <justin.caselman@keysight.com>

_realname=cppdap
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=1.65.r11.g6464cd7
_commit="6464cd7bd0a5639b11902055ca607b53915833fc"
pkgrel=1
pkgdesc="C++ library for the Debug Adapter Protocol (mingw-w64)"
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
url='https://github.com/google/cppdap'
msys2_repository_url='https://github.com/google/cppdap'
msys2_references=(
  'purl: pkg:github/google/cppdap'
)
license=('spdx:Apache-2.0')
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs")
makedepends=(
  "${MINGW_PACKAGE_PREFIX}-cc"
  "${MINGW_PACKAGE_PREFIX}-cmake"
  "${MINGW_PACKAGE_PREFIX}-ninja"
  "${MINGW_PACKAGE_PREFIX}-jsoncpp"
  'git'
)
source=("${_realname}"::"git+${msys2_repository_url}.git#commit=${_commit}")
sha256sums=('0a17579808976f16870fd55a7bd0cb147efbec8023e4985f1cd5b06b2aaab6f5')

pkgver() {
  cd "${_realname}"

  # tags are missing, see https://github.com/google/cppdap/issues/132
  git tag v1.65 37c744c294cbb24943a3913bbb67860d1609008c

  git describe --long --tags ${_commit} | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
}

build() {
  declare -a extra_config
  if check_option "debug" "n"; then
    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
  else
    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
  fi

  LDFLAGS+=" -Wl,--export-all-symbols" \
  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
    cmake \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
      "${extra_config[@]}" \
      -DCPPDAP_USE_EXTERNAL_JSONCPP_PACKAGE=ON \
      -DBUILD_SHARED_LIBS=ON \
      -S ${_realname} \
      -B build-${MSYSTEM}

  cmake --build build-${MSYSTEM}
}

package() {
  DESTDIR="${pkgdir}" cmake --install build-${MSYSTEM}

  install -Dm644 "${srcdir}/${_realname}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
}
