# Maintainer: Dirk Stolle

_realname=benzene
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=20130630
pkgrel=1
pkgdesc="Generator for nonisomorphic fusenes and benzenoids (mingw-w64)"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://github.com/sagemath/sage/tree/develop/build/pkgs/benzene'
msys2_references=(
  'archlinux: benzene'
)
license=('spdx:GPL-2.0-or-later')
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
             "${MINGW_PACKAGE_PREFIX}-make")
source=("https://mirrors.mit.edu/sage/spkg/upstream/benzene/${_realname}-${pkgver}.tar.bz2"
        "LICENSE.txt::https://www.gnu.org/licenses/old-licenses/gpl-2.0.txt"
        "001-fix-forward-declaration.patch")
sha256sums=('63e8662672a007f5b2a727df0ab0e38825c65229fd1060fbf5b5d87b3301e9c6'
            'edaef632cbb643e4e7a221717a6c441a4c1a7c918e6e4d56debc3d8739b233f6'
            '93125b7ab02006f4e9d39e0091a90363eec1cd8bdd7358eb505e4c92a0eb41a1')

prepare() {
  mv src "${_realname}-${pkgver}" && cd "${_realname}-${pkgver}"

  # Honor system's CFLAGS.
  sed -e '/^CFLAGS/d' -i makefile
  # Use system's CC.
  sed -e '/^CC/d' -i makefile

  patch -Np2 -i ../001-fix-forward-declaration.patch
}

build() {
  cd "${_realname}-${pkgver}"

  # Avoid <sys/times.h> which is not available on Windows.
  CFLAGS+=" -DNOLOG"

  make
}

check() {
  cd "${_realname}-${pkgver}"

  # There's no "make check" or even any tests at all for benzene, so let's just invoke the basic
  # executable with some parameters to generate some output and confirm it built properly.
  NUMBER_OF_LINES=$(./benzene 9 B b | wc -l)
  # It should generate 6505 lines for those parameters.
  test $NUMBER_OF_LINES -eq 6505
}

package() {
  cd "${_realname}-${pkgver}"

  install -Dm755 "${_realname}.exe" -t "${pkgdir}${MINGW_PREFIX}/bin/"

  install -Dm644 "../LICENSE.txt" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE.txt"
}
