# Maintainer: Fabrice Creuzot (luigifab) <code~luigifab~fr>

_realname=awf-qt6
binname=$_realname
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
msys2_repository_url='https://github.com/luigifab/awf-extended'

pkgbase=mingw-w64-$_realname
pkgname=${MINGW_PACKAGE_PREFIX}-$_realname
pkgver=4.1.0
pkgrel=1
pkgdesc="Theme preview application for Qt 6"
arch=('any')
url='https://github.com/luigifab/awf-extended'
license=('spdx:GPL-3.0-or-later')
depends=("${MINGW_PACKAGE_PREFIX}-qt6-base" "${MINGW_PACKAGE_PREFIX}-hicolor-icon-theme")
makedepends=("${MINGW_PACKAGE_PREFIX}-autotools" "${MINGW_PACKAGE_PREFIX}-cc")
source=("https://github.com/luigifab/awf-extended/archive/v${pkgver}/awf-extended-${pkgver}.tar.gz")
sha256sums=("2a7b103b383fcc54fd128e1b0fca972e2f23acab2532b9ed053fc40debea1514")

prepare() {
  if [ -d "awf-extended-$pkgver" ]; then
    mv "awf-extended-$pkgver" "$pkgname-$pkgver"
  fi
}

build() {
  cd "$pkgname-$pkgver"
  autoreconf -fi
  cd ..
  mkdir -p "build-${MSYSTEM}" && cd "build-${MSYSTEM}"
  ../$pkgname-$pkgver/configure LDFLAGS="-mwindows" \
    --prefix="${MINGW_PREFIX}" \
    --build="${MINGW_CHOST}" \
    --host="${MINGW_CHOST}" \
    --target="${MINGW_CHOST}" \
    --enable-only-qt6
  make -s
  cd ..
}

package() {
  install -Dpm 755 "build-${MSYSTEM}/src/$binname" "$pkgdir/${MINGW_PREFIX}/bin/$binname.exe"

  for file in $pkgname-$pkgver/src/po/*.po; do
    code=$(basename "$file" .po)
    install -dm 755 "$pkgdir/${MINGW_PREFIX}/share/locale/$code/LC_MESSAGES/"
    msgfmt "$pkgname-$pkgver/src/po/$code.po" -o "$pkgdir/${MINGW_PREFIX}/share/locale/$code/LC_MESSAGES/$binname.mo"
  done
}
