GAP (homalg) - Chapter 9: Bigraded Objects

Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 A B C D E F Bib Ind
[Top of Book] [Contents] [Previous Chapter] [Next Chapter]

[MathJax off]

9 Bigraded Objects
9.1 BigradedObjects: Categories and Representations
9.1-1 IsHomalgBigradedObject
9.1-2 IsHomalgBigradedObjectAssociatedToAnExactCouple
9.1-3 IsHomalgBigradedObjectAssociatedToAFilteredComplex
9.1-4 IsHomalgBigradedObjectAssociatedToABicomplex
9.1-5 IsBigradedObjectOfFinitelyPresentedObjectsRep
9.2 Bigraded Objects: Constructors
9.2-1 HomalgBigradedObject
9.2-2 AsDifferentialObject
9.2-3 DefectOfExactness
9.3 Bigraded Objects: Properties
9.3-1 IsEndowedWithDifferential
9.3-2 IsStableSheet
9.4 Bigraded Objects: Operations and Functions
9.4-1 ByASmallerPresentation

### 9 Bigraded Objects

Bigraded objects in homalg provide a data structure for the sheets (or pages) of spectral sequences.

#### 9.1 BigradedObjects: Categories and Representations

##### 9.1-1 IsHomalgBigradedObject

`‣ IsHomalgBigradedObject`( Er ) | ( category )

Returns: `true` or `false`

The GAP category of homalg bigraded objects.

(It is a subcategory of the GAP category `IsHomalgObject`.)

##### 9.1-2 IsHomalgBigradedObjectAssociatedToAnExactCouple

`‣ IsHomalgBigradedObjectAssociatedToAnExactCouple`( Er ) | ( category )

Returns: `true` or `false`

The GAP category of homalg bigraded objects associated to an exact couple.

(It is a subcategory of the GAP category `IsHomalgBigradedObject`.)

##### 9.1-3 IsHomalgBigradedObjectAssociatedToAFilteredComplex

`‣ IsHomalgBigradedObjectAssociatedToAFilteredComplex`( Er ) | ( category )

Returns: `true` or `false`

The GAP category of homalg bigraded objects associated to a filtered complex.
The \(0\)-th spectral sheet \(E_0\) stemming from a filtration is a bigraded (differential) object, which, in general, does not stem from an exact couple (although \(E_1\), \(E_2\), ... do).

(It is a subcategory of the GAP category `IsHomalgBigradedObject`.)

##### 9.1-4 IsHomalgBigradedObjectAssociatedToABicomplex

`‣ IsHomalgBigradedObjectAssociatedToABicomplex`( Er ) | ( category )

Returns: `true` or `false`

The GAP category of homalg bigraded objects associated to a bicmplex.

(It is a subcategory of the GAP category
`IsHomalgBigradedObjectAssociatedToAFilteredComplex`.)

##### 9.1-5 IsBigradedObjectOfFinitelyPresentedObjectsRep

`‣ IsBigradedObjectOfFinitelyPresentedObjectsRep`( Er ) | ( representation )

Returns: `true` or `false`

The GAP representation of bigraded objects of finitley generated homalg objects.

(It is a representation of the GAP category `IsHomalgBigradedObject` (9.1-1), which is a subrepresentation of the GAP representation `IsFinitelyPresentedObjectRep`.)

#### 9.2 Bigraded Objects: Constructors

##### 9.2-1 HomalgBigradedObject

`‣ HomalgBigradedObject`( B ) | ( operation )

Returns: a homalg bigraded object

This constructor creates a homological (resp. cohomological) bigraded object given a homological (resp. cohomological) homalg bicomplex B (--> `HomalgBicomplex` (8.2-1)). This is nothing but the level zero sheet (without differential) of the spectral sequence associated to the bicomplex B. So it is the double array of homalg objects (i.e. static objects or complexes) in B forgetting the morphisms.

    gap> ZZ := HomalgRingOfIntegers( );
    Z
    gap> M := HomalgMatrix( "[ 2, 3, 4,   5, 6, 7 ]", 2, 3, ZZ );;
    gap> M := LeftPresentation( M );
    <A non-torsion left module presented by 2 relations for 3 generators>
    gap> d := Resolution( M );;
    gap> dd := Hom( d );;
    gap> C := Resolution( dd );;
    gap> CC := Hom( C );
    <A non-zero acyclic complex containing a single morphism of left cocomplexes a\
    t degrees [ 0 .. 1 ]>
    gap> B := HomalgBicomplex( CC );
    <A non-zero bicomplex containing left modules at bidegrees [ 0 .. 1 ]x
    [ -1 .. 0 ]>
    gap> E0 := HomalgBigradedObject( B );
    <A bigraded object containing left modules at bidegrees [ 0 .. 1 ]x
    [ -1 .. 0 ]>
    gap> Display( E0 );
    Level 0:

     * *
     * *

##### 9.2-2 AsDifferentialObject

`‣ AsDifferentialObject`( Er ) | ( method )

Returns: a homalg bigraded object

Add the induced bidegree \(( -r, r - 1 )\) (resp. \(( r, -r + 1 )\)) differential to the level r homological (resp. cohomological) bigraded object stemming from a homological (resp. cohomological) bicomplex. This method performs side effects on its argument Er and returns it.

For an example see `DefectOfExactness` (9.2-3) below.

##### 9.2-3 DefectOfExactness

`‣ DefectOfExactness`( Er ) | ( method )

Returns: a homalg bigraded object

Homological: Compute the homology of a level r differential homological bigraded object, that is the r-th sheet of a homological spectral sequence endowed with a bidegree \(( -r, r - 1 )\) differential. The result is a level r\(+1\) homological bigraded object without its differential.

Cohomological: Compute the cohomology of a level r differential cohomological bigraded object, that is the r-th sheet of a cohomological spectral sequence endowed with a bidegree \(( r, -r + 1 )\) differential. The result is a level r\(+1\) cohomological bigraded object without its differential.

The differential of the resulting level r\(+1\) object can a posteriori be computed using `AsDifferentialObject` (9.2-2). The objects in the result are subquotients of the objects in Er. An object in Er (at a spot \((p,q)\)) is called stable if no passage to a true subquotient occurs at any higher level. Of course, a zero object (at a spot \((p,q)\)) is always stable.

    gap> ZZ := HomalgRingOfIntegers( );
    Z
    gap> M := HomalgMatrix( "[ 2, 3, 4,   5, 6, 7 ]", 2, 3, ZZ );;
    gap> M := LeftPresentation( M );
    <A non-torsion left module presented by 2 relations for 3 generators>
    gap> d := Resolution( M );;
    gap> dd := Hom( d );;
    gap> C := Resolution( dd );;
    gap> CC := Hom( C );
    <A non-zero acyclic complex containing a single morphism of left cocomplexes a\
    t degrees [ 0 .. 1 ]>
    gap> B := HomalgBicomplex( CC );
    <A non-zero bicomplex containing left modules at bidegrees [ 0 .. 1 ]x
    [ -1 .. 0 ]>

Now we construct the spectral sequence associated to the bicomplex \(B\), also called the first spectral sequence:

    gap> I_E0 := HomalgBigradedObject( B );
    <A bigraded object containing left modules at bidegrees [ 0 .. 1 ]x
    [ -1 .. 0 ]>
    gap> Display( I_E0 );
    Level 0:

     * *
     * *
    gap> AsDifferentialObject( I_E0 );
    <A bigraded object with a differential of bidegree
    [ 0, -1 ] containing left modules at bidegrees [ 0 .. 1 ]x[ -1 .. 0 ]>
    gap> I_E0;
    <A bigraded object with a differential of bidegree
    [ 0, -1 ] containing left modules at bidegrees [ 0 .. 1 ]x[ -1 .. 0 ]>
    gap> AsDifferentialObject( I_E0 );
    <A bigraded object with a differential of bidegree
    [ 0, -1 ] containing left modules at bidegrees [ 0 .. 1 ]x[ -1 .. 0 ]>
    gap> I_E1 := DefectOfExactness( I_E0 );
    <A bigraded object containing left modules at bidegrees [ 0 .. 1 ]x
    [ -1 .. 0 ]>
    gap> Display( I_E1 );
    Level 1:

     * *
     . .
    gap> AsDifferentialObject( I_E1 );
    <A bigraded object with a differential of bidegree
    [ -1, 0 ] containing left modules at bidegrees [ 0 .. 1 ]x[ -1 .. 0 ]>
    gap> I_E2 := DefectOfExactness( I_E1 );
    <A bigraded object containing left modules at bidegrees [ 0 .. 1 ]x
    [ -1 .. 0 ]>
    gap> Display( I_E2 );
    Level 2:

     s .
     . .

Legend:

- A star * stands for a nonzero object.

- A dot . stands for a zero object.

- The letter s stands for a nonzero object that became stable.

The second spectral sequence of the bicomplex is, by definition, the spectral sequence associated to the transposed bicomplex:

    gap> tB := TransposedBicomplex( B );
    <A non-zero bicomplex containing left modules at bidegrees [ -1 .. 0 ]x
    [ 0 .. 1 ]>
    gap> II_E0 := HomalgBigradedObject( tB );
    <A bigraded object containing left modules at bidegrees [ -1 .. 0 ]x
    [ 0 .. 1 ]>
    gap> Display( II_E0 );
    Level 0:

     * *
     * *
    gap> AsDifferentialObject( II_E0 );
    <A bigraded object with a differential of bidegree
    [ 0, -1 ] containing left modules at bidegrees [ -1 .. 0 ]x[ 0 .. 1 ]>
    gap> II_E1 := DefectOfExactness( II_E0 );
    <A bigraded object containing left modules at bidegrees [ -1 .. 0 ]x
    [ 0 .. 1 ]>
    gap> Display( II_E1 );
    Level 1:

     * *
     . s
    gap> AsDifferentialObject( II_E1 );
    <A bigraded object with a differential of bidegree
    [ -1, 0 ] containing left modules at bidegrees [ -1 .. 0 ]x[ 0 .. 1 ]>
    gap> II_E2 := DefectOfExactness( II_E1 );
    <A bigraded object containing left modules at bidegrees [ -1 .. 0 ]x
    [ 0 .. 1 ]>
    gap> Display( II_E2 );
    Level 2:

     s .
     . s

#### 9.3 Bigraded Objects: Properties

##### 9.3-1 IsEndowedWithDifferential

`‣ IsEndowedWithDifferential`( Er ) | ( property )

Returns: `true` or `false`

Check if Er is a differential bigraded object.
(no method installed)

##### 9.3-2 IsStableSheet

`‣ IsStableSheet`( Er ) | ( property )

Returns: `true` or `false`

Check if Er is stable.
(no method installed)

#### 9.4 Bigraded Objects: Operations and Functions

##### 9.4-1 ByASmallerPresentation

`‣ ByASmallerPresentation`( Er ) | ( method )

Returns: a homalg bigraded object

It invokes `ByASmallerPresentation` for homalg (static) objects.

    InstallMethod( ByASmallerPresentation,
            "for homalg bigraded objects",
            [ IsHomalgBigradedObject ],

      function( Er )

        List( Flat( ObjectsOfBigradedObject( Er ) ), ByASmallerPresentation );

        return Er;

    end );

This method performs side effects on its argument Er and returns it.

[Top of Book] [Contents] [Previous Chapter] [Next Chapter]
Goto Chapter: Top 1 2 3 4 5 6 7 8 9 10 11 12 A B C D E F Bib Ind

generated by GAPDoc2HTML